Handbook of Advanced Multilevel Analysis

Joop Hox, J. Kyle Roberts, Joop Hox, J. Kyle Roberts

• Publisher: Routledge
• Year: 2011
• Print ISBN: 9781841697222
• eBook ISBN: 9781136951268
• Topic: Psicologia
• Subtopic: Teoria e pratica della didattica

This new handbook is the definitive resource on advanced topics related to multilevel analysis. The editors assembled the top minds in the field to address the latest applications of multilevel modeling as well as the specific difficulties and methodological problems that are becoming more common as more complicated models are developed. Each chapter features examples that use actual datasets. These datasets, as well as the code to run the models, are available on the book's website http://www.hlm-online.com . Each chapter includes an introduction that sets the stage for the material to come and a conclusion.

Divided into five sections, the first provides a broad introduction to the field that serves as a framework for understanding the latter chapters. Part 2 focuses on multilevel latent variable modeling including item response theory and mixture modeling. Section 3 addresses models used for longitudinal data including growth curve and structural equation modeling. Special estimation problems are examined in section 4 including the difficulties involved in estimating survival analysis, Bayesian estimation, bootstrapping, multiple imputation, and complicated models, including generalized linear models, optimal design in multilevel models, and more. The book's concluding section focuses on statistical design issues encountered when doing multilevel modeling including nested designs, analyzing cross-classified models, and dyadic data analysis.

Intended for methodologists, statisticians, and researchers in a variety of fields including psychology, education, and the social and health sciences, this handbook also serves as an excellent text for graduate and PhD level courses in multilevel modeling. A basic knowledge of multilevel modeling is assumed.

Section IV
Special Estimation Problems

APPENDIX 1

In this listing for Example 1, and in subsequent syntax listings, expressions with all uppercase letters are used for SAS-specific syntax, while expressions including lowercase letters are used for user-defined entities. In this example, SocIso is the regressor and bSocIso is its regression coefficient. Note that PROC NLMIXED requires the user to name all model parameters in the syntax. The variable Smk indicates the day of the first smoking event with Sunday = 1, Monday = 2, …, Saturday = 7, and Never Smoked = 8. The final category of Never Smoked represents all right-censored observations (i.e., there is no intermittent right-censoring). Under the complementary log-log link, the cumulative probability of an event occurring up to a particular time point is given by Equation 7.4. Because this is a cumulative probability, the actual probability for a given time point is obtained by subtraction of these cumulative probabilities, except for the first and last categories. The last category (i.e., Never Smoked) is obtained as 1 minus the cumulative probability of smoking up to and including Saturday (i.e., the last day). The parameters a1,a2,…,a7 represent the baseline hazard (i.e., hazard when all covariates equal 0); there are seven of these in this example because the total number of Smk categories is eight. These are akin to the threshold parameters in ordinal regression models and the values of these parameters should be increasing to reflect increased hazard across time. Finally, the variable Schoolid is the cluster (level-2) id, which indicates the students that belong to what schools. The random effect variance attributable to schools is estimated as a standard deviation and named sd. For clustered data, where the cluster variance is thought to be small, it is usually better to estimate the standard deviation than the variance because the latter will be much smaller and close to zero. Also, the random effect, named theta, is multiplied by its standard deviation in the model, as in Equation 7.5, and so it is in standardized form (i.e., the variance of theta equals 1 on the RANDOM statement).

PROC NLMIXED;
PARMS a1 = -1.9 a2 = -1.7 a3 = -1.4 a4 = -1.1 a5 = -.9 a6 = -.8 a7 = -.6
 bSocIso = .1 sd = .2;
 z = bSocIso*SocIso + sd*theta;
IF (Smk = 1) THEN
 p = 1 - EXP( - EXP(a1 + z));
ELSE IF (Smk = 2) THEN
 p =(1 - EXP( - EXP(a2 + z))) - (1 - EXP( - EXP(a1 + z)));
ELSE IF (Smk = 3) THEN
 p =(1 - EXP( - EXP(a3 + z))) - (1 - EXP( - EXP(a2 + z)));
ELSE IF (Smk = 4) THEN
 p =(1 - EXP( - EXP(a4 + z))) - (1 - EXP( - EXP(a3 + z)));
ELSE IF (Smk = 5) THEN
 p =(1 - EXP( - EXP(a5 + z))) - (1 - EXP( - EXP(a4 + z)));
ELSE IF (Smk = 6) THEN
 p =(1 - EXP( - EXP(a6 + z))) - (1 - EXP( - EXP(a5 + z)));
ELSE IF (Smk = 7) THEN
 p =(1 - EXP( - EXP(a7 + z))) - (1 - EXP( - EXP(a6 + z)));
ELSE IF (Smk = 8) THEN
 p = EXP( - EXP(a7+z));
logl = LOG(p);
MODEL Smk ~ GENERAL(logl);
RANDOM theta ~ NORMAL(0,1) SUBJECT = Schoolid;

Users must provide starting values for all parameters on the PARMS statement. To do so, it is beneficial to run the model in stages using estimates from a prior stage as starting values and setting the additional parameters to zero or some small value. For example, one can start by estimating a fixed-effects model to provide starting values for the regression coefficients using SAS PROC PHREG.

In order to test the proportional hazards assumption, one can compare the above model to one in which the effect of SocIso is allowed to vary across the cumulative comparisons of the ordinal outcome (i.e., a nonproportional hazards model). For this, seven response models (named z1, z2, …, z7) with varying effects of SocIso (named bSocIso1, bSocIso2, …, bSocIso7) are defined. The appropriate response models are then indicated in the calculations for the category probabilities.

PROC NLMIXED;
PARMS a1 = -1.9 a2 = -1.7 a3 = -1.4 a4 = -1.1 a5 = -.9 a6 = -.8 a7 = -.6 sd = .2
 bSocIso1 = .1 bSocIso2 = .1 bSocIso3 = .1 bSocIso4 = .1 bSocIso5 = .1
 bSocIso6 = .1 bSocIso7 = .1;
 z1 = bSocIso1*SocIso + sd*theta;
 z2 = bSocIso2*SocIso + sd*theta;
 z3 = bSocIso3*SocIso + sd*theta;
 z4 = bSocIso4*SocIso + sd*theta;
 z5 = bSocIso5*SocIso + sd*theta;
 z6 = bSocIso6*SocIso + sd*theta;
 z7 = bSocIso7*SocIso + sd*theta;
IF (Smk = 1) THEN
 p = 1 - EXP( - EXP(a1 + z1));
ELSE IF (Smk = 2) THEN
 p =(1 - EXP( - EXP(a2 + z2))) - (1 - EXP( - EXP(a1 + z1)));
ELSE IF (Smk = 3) THEN
 p =(1 - EXP( - EXP(a3 + z3))) - (1 - EXP( - EXP(a2 + z2)));
ELSE IF (Smk = 4) THEN
 p =(1 - EXP( - EXP(a4 + z4))) - (1 - EXP( - EXP(a3 + z3)));
ELSE IF (Smk = 5) THEN
 p =(1 - EXP( - EXP(a5 + z5))) - (1 - EXP( - EXP(a4 + z4)));
ELSE IF (Smk = 6) THEN
 p =(1 - EXP( - EXP(a6 + z6))) - (1 - EXP( - EXP(a5 + z5)));
ELSE IF (Smk = 7) THEN
 p =(1 - EXP( - EXP(a7 + z7))) - (1 - EXP( - EXP(a6 + z6)));
ELSE IF (Smk = 8) THEN
 p = EXP( - EXP(a7 + z7));
logl = LOG(p);
MODEL Smk ~ GENERAL(logl);
RANDOM theta ~ NORMAL(0,1) SUBJECT = Schoolid;

APPENDIX 2

For Example 2, Male, Cc, and Tv are indicator variables of male, CC intervention, and TV intervention, respe...

Table of contents

• Contents
• Preface
• Section I Introduction
• Section II Multilevel Latent Variable Modeling (LVM)
• Section III Multilevel Models for Longitudinal Data
• Section IV Special Estimation Problems
• Section V Specific Statistical Issues
• Author Index
• Subject Index